Kode që ndalon ofendimet Në IRC Për Op

[Universal]

Ky kodim bën të mundur ndalimin e sharjeve në kanalet e bisedimeve në linjë për Operatorat e IRC.
Për ta përdorur fare e lehtë shtypni te Scripts Editor për ata që dinë anglisht dhe pastaj shtypni remote aty majtas lart shtypni File==>New dhe ngjisni linjat e mëposhtme duke shtypur oki ne fund.
Kam përkthyer pjesët që janë më të nevojshme por mund ta përktheni tërësisht nëse keni dëshirë

on *:text:*:#: {
  if ($1 == !badword) && ($_chan($chan)) && ($istok(on off,$2,32)) && ($nick isop $chan) {
    set %_badword $iif($2 == off,$v2,on)
    msg $chan Badword protection is now %_badword
  }
  else {
    if (%_badword == on) && ($me isop $chan) && ($nick !isop $chan) && ($_chan($chan)) {
      ;  Ndryshoni fjalët e mëposhtme sipas nevojës.
      var %badword = *****,qën,shkërdhatë,ta qi motrën, ta qi jetën,ta qi zotin, %a = $numtok(%badword,44)
      while (%a) {
        var %bchk = $gettok(%badword,%a,44)
        if (%bchk isin $1-) {
          inc $+(%,badword,.,$nick,.,$chan)
          var %times = $($+(%,badword,.,$nick,.,$chan),2)
          if (%times == 1) {
            .notice $nick Të lutem mos përdor fjalë fyese në $chan $nick $+ . Keni thyer regullat %times time. (Keni thënë badword: %bchk $+ )
          }
          elseif (%times == 2) {
            kick $chan $nick Të lutem mos përdor fjalë fyese në $chan $nick $+ . Keni thyer regullat %times times. Herën tjetër do ndaloheni! (Keni thënë badword: %bchk $+ )
          }
          elseif (%times > 2) {
            ban -ku900 $chan $nick 2 Ju paralajmërova dy herë deri tani. Mireupafshim. 15 minuta ban.
            unset $+(%,badword,.,$nick,.,$chan)
          }
        }
        dec %a
      }
    }
  }
}

alias -l _chan {
  ;  Change the channels for the bot to work on below, to make it work in all channels just input "#".
  var %a = #, %b = $numtok(%a,44)
  while (%b) {
    if ($1 == $gettok(%a,%b,44)) || (%a == $chr(35)) {
      return $true
    }
    dec %b
  }
}

on *:exit: {
  unset %badword.*
}

menu channel {
  .Turn badword filter $iif(%_badword == on,off,on) : set %_badword $iif(%_badword == on,off,on)
}

 

[Master]

Cna kujtove kohen e ndertimit te scripteve